Console exe

A console application is a computer program designed to be used via a text-only computer interface.

A text-only interface could be a text terminal, the command line interface of the operating systems (Unix, DOS, etc.) or the text-based interface included with some Graphical User Interface (GUI) operating systems, such as the Win32 console in Microsoft Windows.

A user typically interacts with a console application using only a keyboard and display screen, as opposed to GUI applications, which normally require the use of a mouse or other pointing device.

Many console applications such as command line interpreters are command line tools, but numerous Text User Interface (TUI) programs also exist.

As the speed and ease-of-use of GUI applications have improved over time, the use of console applications has greatly diminished, but not disappeared. Some users simply prefer console based applications, while some organizations still rely on existing console applications to handle key data processing tasks.

A Console Program:

REM example showing how to find your local IP address and basic winsock startup
REM Compile as a CONSOLE target
$use "wsock32.lib"

TYPE WSADataType
   DEF wVersion:WORD  
   DEF wHighVersion:WORD  
   DEF strDescription[257]:ISTRING  
   DEF strSystemStatus[129]:ISTRING  
   DEF iMaxSockets:INT  
   DEF iMaxUdpDg:INT  
   DEF lpVendorInfo:POINTER  
ENDTYPE

Type HostEnt
    DEF h_name :POINTER
    DEF h_aliases :POINTER
    DEF h_addrtype:WORD
    DEF h_length:WORD
    DEF addrlist :POINTER
EndType

Declare IMPORT,gethostbyname(hostname:string),HostEnt
Declare IMPORT,gethostname(hostname:string, namelen :int),int
Declare IMPORT,inet_ntoa(inn :POINTER),STRING
Declare IMPORT,WSAStartup(wVR :int, lpWSAD:POINTER),int
Declare IMPORT,WSACleanup(),int

CONST WSVER1 = 0x101
CONST WSVER2 = 0x202

WSA_NoName = "Unknown"

DEF localname,ip as string
DEF he as HostEnt

OPENCONSOLE

IF(StartWinsock(""))
	localname = GetLocalHostName()
	print "Local name = ",localname
	he = gethostbyname(localname)
	REM addrlist is a pointer to a pointer
	REM so resolve twice
	ip = inet_ntoa(he.*<POINTER>*<POINTER>addrlist)
	REM display the IP address
	print "IP Address: ",ip
	WSACleanup()
ENDIF

DO:UNTIL INKEY$ <> ""
CLOSECONSOLE
END

Sub GetLocalHostName(),STRING
    DEF retc:int
    DEF namestr:string
	namestr="EMPTY"
	retc=gethostname(namestr, 256)
	If retc <>0
       namestr = WSA_NoName
	Endif
Return namestr
ENDSUB

Sub StartWinsock(sDescription:string),int
	DEF StartupData:WSADataType
	DEF sw_ret:int
	DEF stat:int

stat=WSAStartup( WSVER2 , StartupData)
	If stat=0
		sw_ret = 1
		
		Print "wVersion=",showver(StartupData.wVersion)
		Print "wHighVersion=",showver(StartupData.wHighVersion)
		Print "szDescription=",
		Print StartupData.strDescription
		Print "szSystemStatus=",
		Print StartupData.strSystemStatus
		'Print "iMaxSockets=",StartupData.iMaxSockets 
		'Print "iMaxUdpDg=",StartupData.iMaxUdpDg
	Else
		sw_ret=0
	EndIf
Return sw_ret
ENDSUB

Sub ShowVer(vernum:int),STRING
DEF verstr:string
	if vernum=WSVER1 
		verstr="1.1"
	endif
	if vernum=WSVER2 
		verstr="2.1"
	endif
Return verstr
ENDSUB

How it works

Let's look at the structure and function of some of the commands that make up the program.
First, you will note some comments at the top of the file. Comments in ebasic can be indicated by:

REM - Legacy Basic Remark statement
/* */ - C and other language comment delimiter
' - a single line comment

Comments are used to document things you might otherwise forget or just to explaine something.
You determine the comment - just note that you will for get things so comments really help.

Anything noted as a comment in the source code is ignored by the compiler.

The next line is the '$use "wsock32.dll" directive. This is a pre-processor command that tells the Linker pass of the compiler to import this library.

The next items are the TYPE declarations or UDT's (User Defined Type).
They define grouped data storage. The members of a UDT can be any built-in or user defined type. Use the DEF statement for defining the individual data members.
You must end the definition with the ENDTYPE statement.

Next you see a group of declare statements.
These statements tell the compiler that you want to declare a local, external, or import function and its parameters.
In this case we are telling the compiler that we will be using several external subroutines.

Next we define a couple of Constants. A constant is a special tag that assignes a name to a variable. This makes it eaiser for us to remember items as opposed to values.

Next we define a couple of variables and their type so that when we reference them in the program the compiler knows what we are talking about.

Next we issue the OPENCONSOLE command - this instructs the compiler to build our console (DOS) window.

Now we contact the subroutine StartWinSock().
Sub StartWinsock(sDescription:string),int DEF StartupData:WSADataType DEF sw_ret:int DEF stat:int stat=WSAStartup( WSVER2 , StartupData) If stat=0 sw_ret = 1 Print "wVersion=",showver(StartupData.wVersion) Print "wHighVersion=",showver(StartupData.wHighVersion) Print "szDescription=", Print StartupData.strDescription Print "szSystemStatus=", Print StartupData.strSystemStatus 'Print "iMaxSockets=",StartupData.iMaxSockets 'Print "iMaxUdpDg=",StartupData.iMaxUdpDg Else sw_ret=0 EndIf Return sw_ret ENDSUB
This routine will return a non-zero value if successful.
If the IF statement evaluates to 'TRUE' (not zero) several subroutines within our program are called to produce our output.
Note that the ENDIF closes the IF command.

Next you see:
DO:UNTIL INKEY$ <> "" CLOSECONSOLE END
This code keeps the CONSOLE open until we hit a key. This will allow the output from the subroutines to stay on the screen so that we can read it.

This has been a simple example of a console program. Console programs tend to be for a specific purpose. You will need to define your purpose and build your console application as needed.

Next Section